 |
The Question is:
I'm connecting a ZyXEL U1496-E modem to a CXY08 card in my VAX 4000-200. Is
there a simple command procedure for dialing out TXA0: to another remote
modem hooked up to a printer?
I've tried :
$set noon
$allocate TXA0:
$copy sys$input TXA0:
$wait 00:00:05
ATZ
$wait 00:00:05
$copy sys$input TXA0:
ATDT 9,2298628#
$WAIT 00:00:10
ATH0
$wait 00:00:03
$deallocate TXA0:
$exit
To no avail, modem blinks then drops. Can you point me in the right
direction?
The Answer is :
The OpenVMS Wizard suspects your problem is that COPY is opening and
closing channels to the modem. Here is an old command procedure for
creating a SLIP session which uses DCL to communicate with a modem,
provided for illistrative purposes. Note that the READ/PROMPT command
is used, and that the READ commands have timeouts.
The dialing and authentication is intended to be performed manually
during the SET HOST/DTE, but could have been performed using the same
mechanism, were it not a security risk.
$ SET NOON
$ modem="TTA2:"
$ cr[0,8]=13
$ SET PROCESS/PRIVILEGE=(SYSPRV,LOG_IO)
$ Retry: ON WARNING THEN GOTO Retry
$ ALLOCATE 'modem'
$ SET NOON
$ SET TERMINAL/NOHOSTSYNC/NOTTSYNC/TYPEAHEAD/NOHANGUP-
/NODISCONNECT/NOMODEM/NOECHO/NOLOCAL/NOWRAP-
/PASTHRU/ALTYPEAHEAD/PERM/SPEED=19200 'modem'
$ SHOW TERM 'modem'
$ INQUIRE ans "turn modem on and hit return"
$ WRITE SYS$OUTPUT "Setting up modem""
$ OPEN/READ/WRITE mdm 'modem'
$ CALL TellModem "atq0v1e1"
$ CALL TellModem "atk1m1x4"
$ CALL TellModem "at&b0&c0&d0"
$ CALL TellModem "at&m0&r2&t5"
$ CALL TellModem "at*e9*f0*g1*m2"
$ CALL TellModem "ats2=43"
$ CALL TellModem "ats9=6"
$ CALL TellModem "at*o"
$ CLOSE mdm
$ DEFINE/USER SYS$INPUT SYS$COMMAND
$ SET HOST/DTE 'modem'
$ DEALLOCATE 'modem'
$ UCX SET INTERFACE SL2 /HOST=10.100.00.100 -
/SERIAL='modem' -
/NETWORK=255.255.255.0 -
/COMPRESS=ON
$ EXIT
$ TellModem: SUBROUTINE
$ WRITE SYS$OUTPUT "Sending modem ''p1'"
$ READ/TIME=1/ERR=noresp/PROMPT="''p1'''cr'" mdm response
$ SHOW SYMBOL response
$ retry: READ/TIME=1/ERR=endresponse/PROMPT="" mdm response
$ SHOW SYMBOL response
$ GOTO retry
$ noresp:
$ stat=$STATUS
$ WRITE SYS$OUTPUT "No response, status=''stat'"
$ endresponse: EXIT
$ ENDSUBROUTINE
|
|
|
|
|
