HP OpenVMS Systems Documentation
OpenVMS DCL Dictionary
This MOUNT command requests the operator to mount the volume TESTSYS on the device DYA1. Because DYA1 is allocated to another user, the device cannot be mounted. In this case, the user can wait for the device to become available, redirect the mount to another device, or abort the mount. Here, the user remains in operator-assisted mount waiting for the process that is using the device to deallocate it.
At this point, because the device is available but no volume is mounted, the original mount request is canceled, and a new request to mount TESTSYS is issued. Finally, the operator places the volume in the drive and lets MOUNT retry the mount. When the mount completes, the request is canceled.
Invokes the OpenVMS National Character Set (NCS) utility, which provides a convenient method of implementing alternative (non-ASCII) string collating sequences, typically using subsets of the DEC Multinational character set. NCS also facilitates the implementation of string conversion functions.
Performs a specified action when a command or program executed within a command procedure encounters an error condition or is interrupted by Ctrl/Y. The specified actions are performed only if the command interpreter is enabled for error checking or Ctrl/Y interrupts (the default conditions). Use the ON command only in a command procedure.
ON condition THEN [$] command
During the execution of a command procedure, the command interpreter checks the condition code returned from each command or program that executes. With the ON command, you can establish a course of action for the command interpreter to take based on the result of the check.
$ ON SEVERE_ERROR THEN CONTINUE
A command procedure that contains this statement continues to execute normally when a warning or error occurs during execution. When a severe error occurs, the ON statement signals the procedure to execute the next statement anyway. Once the statement has been executed as a result of the severe error condition, the default action (ON ERROR THEN EXIT) is reinstated.
$ ON ERROR THEN GOTO BYPASS $ RUN A $ RUN B . . . $ EXIT $ BYPASS: $ RUN C
If either program A or program B returns a status code with a severity level of error or severe error, control is transferred to the statement labeled BYPASS and program C is run.
$ ON WARNING THEN EXIT . . . $ SET NOON $ RUN [SSTEST]LIBRA $ SET ON . . .
The ON command requests that the procedure exit when any warning, error, or severe error occurs. Later, the SET NOON command disables error checking before executing the RUN command. Regardless of any status code returned by the program LIBRA.EXE, the procedure continues. The next command, SET ON, reenables error checking and reestablishes the most recent ON condition.
$ ON CONTROL_Y THEN GOTO CTRL_EXIT . . . $ CTRL_EXIT: $ CLOSE INFILE $ CLOSE OUTFILE $ EXIT
The ON command specifies action to be taken when Ctrl/Y is pressed during the execution of this procedure: the GOTO command transfers control to the line labeled CTRL_EXIT. At CTRL_EXIT, the procedure performs cleanup operations (in this example, closing files and exiting).
Opens a file for reading, writing, or both; assigns a logical name to a file; and places the name in the process logical name table.
See the qualifier descriptions for restrictions.
OPEN logical-name[:] filespec
logical-name[:]Specifies the logical name and a character string to be assigned to the file.
filespecSpecifies the name of the file or device being opened for input or output. The file type defaults to DAT. The asterisk (*) and the percent sign (%) wildcard characters are not allowed.
To create a new, sequential file, specify the /WRITE qualifier. See the description of the /WRITE qualifier for more information.
A file can be opened for either reading or writing, or for both reading and writing. After the file is opened, it is available for input or output at the command level with the READ and WRITE commands.
The OPEN command opens files as process permanent. Therefore, these files remain open until you close them with the CLOSE command, or until you log out. If a command procedure that opens a file terminates without closing an open file, the file remains open; the command interpreter does not automatically close it. The OPEN command uses OpenVMS RMS to open files, and is subject to RMS restrictions on using process-permanent files. The OPEN command opens sequential, relative, or indexed sequential files.
The logical devices SYS$INPUT, SYS$OUTPUT, SYS$COMMAND, and SYS$ERROR do not have to be opened explicitly before they can be read or written at the command level. All other files must be opened explicitly.
Do not use the same logical name when you open different files. If you specify a logical name with the OPEN command and the logical name is currently assigned to another file, no warning message is issued; however, the file is not opened, and the next READ request will access the file to which the logical name was originally assigned.
You can enter more than one OPEN command for the same file and assign it different logical names if you use the /SHARE qualifier the first time the file is opened. Also, if you open the file by using the /SHARE=READ or the /SHARE=WRITE qualifier, other users can access the file with the TYPE or the SEARCH command.
When you use the OPEN command to create a new file, variable fixed control (VFC) record format is used. Concatenating a file of this record format with a file of another record format might be impossible due to record format incompatibilities. To avoid the VFC format, use the CREATE command to create the file.
When the OPEN command is specified on an existing file, the record type of that file is used.
/APPENDOpens an existing file for writing and positions the record pointer at the end-of-file (EOF). New records are added to the end of the file.
Only sequential files allow more than one user to append records concurrently.
Use the /APPEND qualifier only to add records to an existing file. The /APPEND and the /WRITE qualifiers are mutually exclusive.
/ERROR=labelTransfers control to the location specified by the label keyword (in a command procedure) if the open operation results in an error. The error routine specified for this qualifier overrides any ON condition action specified. If the /ERROR qualifier is not specified, the current ON condition action is taken.
If an error occurs and the target label is successfully given control, the global symbol $STATUS retains the code for the error that caused the error path to be taken.
/READ (default)Opens the file for reading. If you specify the /READ qualifier without the /WRITE qualifier, you must specify an existing file.
/SHARE[=option]Opens the specified file as a shareable file to allow other users read or write access. If you specify the /SHARE=READ qualifier, other users are allowed read (R) access to the file, but not write (W) access. If you specify the /SHARE=WRITE or the /SHARE qualifier with no option, users are allowed read and write access to the specified file.
If the /SHARE qualifier is not present, other users are allowed only read access to the specified file.
/WRITEOpens the file for writing. The following restrictions apply to the /WRITE qualifier:
- Use the /WRITE qualifier to open and create a new, sequential file. If the file specification on an OPEN/WRITE command does not include a file version number, and if a file with the specified file name and file type already exists, a new file with a version number one greater than the existing file is created.
- Use the /READ qualifier with the /WRITE qualifier to open an existing file. When the file is opened, the pointer is positioned to the beginning of the file. (This differs from OPEN/APPEND, which positions the pointer at the end of the file.) You cannot use OPEN/READ/WRITE to create a new file.
- The /WRITE and the /APPEND qualifiers are mutually exclusive.
$ OPEN INPUT_FILE AVERAGE.DAT $ READ_LOOP: $ READ/END_OF_FILE=ENDIT INPUT_FILE NUM . . . $ GOTO READ_LOOP $ ENDIT: $ CLOSE INPUT_FILE
The OPEN command opens the file named AVERAGE.DAT as an input file and assigns it the logical name INPUT_FILE. The file is opened with read access because the /READ qualifier is present by default. The READ command reads a record from the logical file INPUT_FILE into the symbol named NUM. The procedure executes the lines between the labels READ_LOOP and ENDIT until the end of the file is reached. At the end of the file, the CLOSE command closes the file.
$ OPEN/WRITE/ERROR=OPEN_ERROR OUTPUT_FILE TEMP.OUT $ COUNT = 0 $ WRITE_LOOP: $ COUNT = COUNT + 1 $ IF COUNT .EQ. 11 THEN GOTO ENDIT $ WRITE OUTPUT_FILE "Count is ''COUNT'." . . . $ GOTO WRITE_LOOP $ ENDIT: $ CLOSE OUTPUT_FILE $ EXIT $ $ OPEN_ERROR: $ WRITE SYS$OUTPUT "Cannot open file TEMP.OUT" $ EXIT
The OPEN command with the /WRITE qualifier creates the file TEMP.OUT and assigns it the logical name OUTPUT_FILE. TEMP.OUT is a sequential file.
The /ERROR qualifier specifies that if any error occurs while opening the file, the command interpreter should transfer control to the line at the label OPEN_ERROR. The command procedure writes records to the file TEMP.OUT until the symbol COUNT equals 11.
$ OPEN/READ INPUT_FILE TRNTO::DKA0:[COST]INVENTORY.DAT $ READ_LOOP: $ READ/END_OF_FILE=ENDIT INPUT_FILE NUM $ FIRST_CHAR = F$EXTRACT(0,1,NUM) $ WRITE SYS$OUTPUT FIRST_CHAR $ GOTO READ_LOOP $ ENDIT: $ CLOSE INPUT_FILE
This command procedure opens the file INVENTORY.DAT located at remote node TRNTO as an input file, and assigns it the logical name INPUT_FILE. The READ command reads a record from the logical file INPUT_FILE into the symbol named NUM. The next two commands extract the first character from the record and write the character to the SYS$OUTPUT device. These two steps occur for all records in the file until the procedure reaches the end-of-file (EOF). At this point, the CLOSE command closes the file and deassigns the logical name INPUT_FILE.
Provides the password associated with the user name that you specify with the JOB card when you submit a batch job through a card reader. Although the PASSWORD card is required, the password on the card is optional if the account has a null password.
The PASSWORD command is valid only in a batch job submitted through a card reader and requires that a dollar sign ($) precede the PASSWORD command on the card.
To change your password, use the SET PASSWORD command. For information on this command, see the description of SET PASSWORD.
passwordSpecifies the password associated with the user name specified with the JOB command. The password can be 1 to 31 characters long.
If you are submitting the job from an account with a null password, omit the password specifier on the PASSWORD card.
The PASSWORD command is used in conjunction with the JOB command. The JOB card identifies the user submitting the batch job through a card reader and is followed by a PASSWORD card giving the password. The password is checked by the system to verify that it matches the password associated with the user name on the JOB card. If the passwords do not match, the job is rejected.
Note that you might want to suppress printing when you originally keypunch the PASSWORD card to prohibit other users from seeing the password when the PASSWORD card is in use.